Steps for now (I'm not happy at all on how to get rid of VCRUNTIME140.DLL):

1. Install Visual Studio 2015 community edition from https://www.visualstudio.com/en-us/downloads/download-visual-studio-vs.aspx (as of writing: http://download.microsoft.com/download/D/2/3/D23F4D0F-BA2D-4600-8725-6CCECEA05196/vs_community_ENU.exe or http://download.microsoft.com/download/b/e/d/bedddfc4-55f4-4748-90a8-ffe38a40e89f/vs2015.3.com_enu.iso )
2. Download CMake via https://cmake.org/download/ back then https://cmake.org/files/v3.6/cmake-3.6.2-win64-x64.msi
3. Install and ensure to add CMake to the PATH for all users:

4. Run this script on a new command-line:

   git clone https://github.com/libssh2/libssh2.git
   pushd libssh2
   
   :: Try to force Static libraries (so VCRUNTIME140.DLL is not needed; hopefully this links libvcruntime.lib instead of vcruntime.lib)
   pushd cmake
   > c_flag_overrides.cmake type NUL
   >> c_flag_overrides.cmake echo    if(MSVC)
   >> c_flag_overrides.cmake echo        set(CMAKE_C_FLAGS_DEBUG_INIT "/D_DEBUG /MTd /Zi /Ob0 /Od /RTC1")
   >> c_flag_overrides.cmake echo        set(CMAKE_C_FLAGS_MINSIZEREL_INIT     "/MT /O1 /Ob1 /D NDEBUG")
   >> c_flag_overrides.cmake echo        set(CMAKE_C_FLAGS_RELEASE_INIT        "/MT /O2 /Ob2 /D NDEBUG")
   >> c_flag_overrides.cmake echo        set(CMAKE_C_FLAGS_RELWITHDEBINFO_INIT "/MT /Zi /O2 /Ob1 /D NDEBUG")
   >> c_flag_overrides.cmake echo    endif()
   
   > cxx_flag_overrides.cmake type NUL
   >> cxx_flag_overrides.cmake echo    if(MSVC)
   >> cxx_flag_overrides.cmake echo        set(CMAKE_CXX_FLAGS_DEBUG_INIT "/D_DEBUG /MTd /Zi /Ob0 /Od /RTC1")
   >> cxx_flag_overrides.cmake echo        set(CMAKE_CXX_FLAGS_MINSIZEREL_INIT     "/MT /O1 /Ob1 /D NDEBUG")
   >> cxx_flag_overrides.cmake echo        set(CMAKE_CXX_FLAGS_RELEASE_INIT        "/MT /O2 /Ob2 /D NDEBUG")
   >> cxx_flag_overrides.cmake echo        set(CMAKE_CXX_FLAGS_RELWITHDEBINFO_INIT "/MT /Zi /O2 /Ob1 /D NDEBUG")
   >> cxx_flag_overrides.cmake echo    endif()
   
   > MSVCC_static_linking.cmake type NUL
   >> MSVCC_static_linking.cmake echo set(CMAKE_USER_MAKE_RULES_OVERRIDE
   >> MSVCC_static_linking.cmake echo    ${CMAKE_CURRENT_SOURCE_DIR}/cmake/c_flag_overrides.cmake)
   >> MSVCC_static_linking.cmake echo set(CMAKE_USER_MAKE_RULES_OVERRIDE_CXX
   >> MSVCC_static_linking.cmake echo    ${CMAKE_CURRENT_SOURCE_DIR}/cmake/cxx_flag_overrides.cmake)
   
   >> max_warnings.cmake echo include(MSVCC_static_linking)
   popd
   
   :: the above trick with C*_FLAGS* doesn't work so go the PowerShell way of globally replacing the generated VC++ project files
   :: http://stackoverflow.com/questions/251557/escape-angle-brackets-in-a-windows-command-prompt
   > fix-vcxproj-files.ps1 type NUL
   >> fix-vcxproj-files.ps1 echo  $projectFiles = Get-ChildItem . *.vcxproj -Recurse
   >> fix-vcxproj-files.ps1 echo  foreach ($projectFile in $projectFiles) {
   >> fix-vcxproj-files.ps1 echo      (Get-Content $projectFile.PSPath).
   >> fix-vcxproj-files.ps1 echo        Replace('^<UseOfMfc^>false^</UseOfMfc^>', '^<UseOfMfc^>Static^</UseOfMfc^>').
   >> fix-vcxproj-files.ps1 echo        Replace('^<RuntimeLibrary^>MultiThreadedDebugDLL^</RuntimeLibrary^>', '^<RuntimeLibrary^>MultiThreadedDebug^</RuntimeLibrary^>').
   >> fix-vcxproj-files.ps1 echo        Replace('^<RuntimeLibrary^>MultiThreadedDLL^</RuntimeLibrary^>', '^<RuntimeLibrary^>MultiThreaded^</RuntimeLibrary^>') ^|
   >> fix-vcxproj-files.ps1 echo      Set-Content $projectFile.PSPath
   >> fix-vcxproj-files.ps1 echo  }
   
   mkdir buildWin64
   pushd buildWin64
   :: Generate build for MSVS 2015
   ::cmake .. -G"Visual Studio 14 Win64" -D"BUILD_SHARED_LIBS=1" -D"CMAKE_BUILD_TYPE=Release" -D"OPENSSL_ROOT_DIR=../../openssl" -D"OPENSSL_LIBRARIES=../../openssl/ssl"
   cmake .. -G"Visual Studio 14 Win64" -D"BUILD_SHARED_LIBS=1" -D"CMAKE_BUILD_TYPE=Release"
   powershell -file ..\fix-vcxproj-files.ps1
   :: this fails bitching about v100 not being there:
   :: cmake --build . --config "Visual Studio 14 Win64"
   :: this just works:
   set Platform=
   call "C:\Program Files (x86)\Microsoft Visual Studio 14.0\VC\bin\amd64\vcvars64.bat"
   call msbuild libssh2.sln /p:Configuration=Release /p:Platform=x64
   dumpbin /headers example\Release\libssh2.dll | find "machine"
   dumpbin /all example\Release\libssh2.dll > example\Release\libssh2.dll.dumpbin.txt
   tdump64 example\Release\libssh2.dll > example\Release\libssh2.dll.tdump.txt
   popd
   
   mkdir buildWin32
   pushd buildWin32
   :: Generate build for MSVS 2015
   :: cmake .. -G"Visual Studio 14" -D"BUILD_SHARED_LIBS=1" -D"CMAKE_BUILD_TYPE=Release" -D"OPENSSL_ROOT_DIR=../../openssl" -D"OPENSSL_LIBRARIES=../../openssl/ssl"
   cmake .. -G"Visual Studio 14" -D"BUILD_SHARED_LIBS=1" -D"CMAKE_BUILD_TYPE=Release"
   powershell -file ..\fix-vcxproj-files.ps1
   set Platform=
   call "C:\Program Files (x86)\Microsoft Visual Studio 14.0\VC\bin\vcvars32.bat"
   call msbuild libssh2.sln /p:Configuration=Release /p:Platform=Win32
   dumpbin /headers example\Release\libssh2.dll | find "machine"
   dumpbin /all example\Release\libssh2.dll > example\Release\libssh2.dll.dumpbin.txt
   tdump example\Release\libssh2.dll > example\Release\libssh2.dll.tdump.txt
   popd
   
   popd
   

The above trick will create a libssh2.dll that is statically linked with libvcruntime.lib instead of vcruntime.lib which means you do not need to have VCRUNTIME140.DLL or VCRUNTIME140D.DLL on your system.