Created
November 17, 2013 06:20
-
-
Save alumican/7510012 to your computer and use it in GitHub Desktop.
クルクルローディングつくる君
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
/* | |
クルクルローディングつくる君 | |
使い方 | |
1. ライブラリにBarシンボルを作る(基準点を中心に回転する) | |
2. 以下のスクリプトを1フレーム目にコピペしてする | |
3. パラメータを適当に変える | |
4. 書き出し設定をAIRにしてムービープレビューする | |
5. デスクトップに保存されている | |
*/ | |
var baseName:String = "loading"; | |
var numBar:int = 12; | |
var startAlpha:Number = 0.7; | |
var endAlpha:Number = 0.2; | |
var clockwise:Boolean = true; | |
import flash.filesystem.*; | |
var container:Sprite = Sprite(addChild(new Sprite())); | |
container.x = stage.stageWidth / 2; | |
container.y = stage.stageHeight / 2; | |
for (var i:int = 0; i < numBar; ++i) { | |
var bar:Sprite = Sprite(container.addChild(new Bar())); | |
bar.rotation = 360 * (clockwise ? numBar - i : i) / numBar; | |
bar.alpha = startAlpha + (endAlpha - startAlpha) * i / (numBar - 1); | |
} | |
var frameIndex:int = 0; | |
var dir:File = File.desktopDirectory.resolvePath(baseName); | |
var bmd:BitmapData = new BitmapData(container.width, container.height, true); | |
var clear:BitmapData = new BitmapData(bmd.width, bmd.height, true, 0x0); | |
addEventListener(Event.ENTER_FRAME, function(event:Event):void { | |
var m:Matrix = new Matrix(); | |
m.rotate((container.rotation = 360 * (clockwise ? frameIndex : (numBar - frameIndex)) / numBar) * Math.PI / 180); | |
m.translate(container.width / 2, container.height / 2); | |
bmd.copyPixels(clear, clear.rect, new Point()); | |
bmd.draw(container, m); | |
var bytes:ByteArray = encode(bmd); | |
var fs:FileStream = new FileStream(); | |
var file:File = dir.resolvePath(baseName + "_" + frameIndex + ".png"); | |
trace(file.nativePath); | |
fs.open(file, FileMode.WRITE); | |
fs.writeBytes(bytes); | |
fs.close(); | |
bytes.clear(); | |
if (++frameIndex == numBar) | |
NativeApplication.nativeApplication.exit(); | |
}); | |
//----- DEPENDANCE | |
/* | |
Copyright (c) 2008, Adobe Systems Incorporated | |
All rights reserved. | |
Redistribution and use in source and binary forms, with or without | |
modification, are permitted provided that the following conditions are | |
met: | |
* Redistributions of source code must retain the above copyright notice, | |
this list of conditions and the following disclaimer. | |
* Redistributions in binary form must reproduce the above copyright | |
notice, this list of conditions and the following disclaimer in the | |
documentation and/or other materials provided with the distribution. | |
* Neither the name of Adobe Systems Incorporated nor the names of its | |
contributors may be used to endorse or promote products derived from | |
this software without specific prior written permission. | |
THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS | |
IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, | |
THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR | |
PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR | |
CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, | |
EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, | |
PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR | |
PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF | |
LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING | |
NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS | |
SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. | |
*/ | |
import flash.geom.*; | |
import flash.display.Bitmap; | |
import flash.display.BitmapData; | |
import flash.utils.ByteArray; | |
/** | |
* Class that converts BitmapData into a valid PNG | |
*/ | |
/** | |
* Created a PNG image from the specified BitmapData | |
* | |
* @param image The BitmapData that will be converted into the PNG format. | |
* @return a ByteArray representing the PNG encoded image data. | |
* @langversion ActionScript 3.0 | |
* @playerversion Flash 9.0 | |
* @tiptext | |
*/ | |
function encode(img:BitmapData):ByteArray { | |
// Create output byte array | |
var png:ByteArray = new ByteArray(); | |
// Write PNG signature | |
png.writeUnsignedInt(0x89504e47); | |
png.writeUnsignedInt(0x0D0A1A0A); | |
// Build IHDR chunk | |
var IHDR:ByteArray = new ByteArray(); | |
IHDR.writeInt(img.width); | |
IHDR.writeInt(img.height); | |
IHDR.writeUnsignedInt(0x08060000); // 32bit RGBA | |
IHDR.writeByte(0); | |
writeChunk(png,0x49484452,IHDR); | |
// Build IDAT chunk | |
var IDAT:ByteArray= new ByteArray(); | |
for(var i:int=0;i < img.height;i++) { | |
// no filter | |
IDAT.writeByte(0); | |
var p:uint; | |
var j:int; | |
if ( !img.transparent ) { | |
for(j=0;j < img.width;j++) { | |
p = img.getPixel(j,i); | |
IDAT.writeUnsignedInt( | |
uint(((p&0xFFFFFF) << 8)|0xFF)); | |
} | |
} else { | |
for(j=0;j < img.width;j++) { | |
p = img.getPixel32(j,i); | |
IDAT.writeUnsignedInt( | |
uint(((p&0xFFFFFF) << 8)| | |
(p>>>24))); | |
} | |
} | |
} | |
IDAT.compress(); | |
writeChunk(png,0x49444154,IDAT); | |
// Build IEND chunk | |
writeChunk(png,0x49454E44,null); | |
// return PNG | |
return png; | |
} | |
var crcTable:Array; | |
var crcTableComputed:Boolean = false; | |
function writeChunk(png:ByteArray, | |
type:uint, data:ByteArray):void { | |
if (!crcTableComputed) { | |
crcTableComputed = true; | |
crcTable = []; | |
var c:uint; | |
for (var n:uint = 0; n < 256; n++) { | |
c = n; | |
for (var k:uint = 0; k < 8; k++) { | |
if (c & 1) { | |
c = uint(uint(0xedb88320) ^ | |
uint(c >>> 1)); | |
} else { | |
c = uint(c >>> 1); | |
} | |
} | |
crcTable[n] = c; | |
} | |
} | |
var len:uint = 0; | |
if (data != null) { | |
len = data.length; | |
} | |
png.writeUnsignedInt(len); | |
var p:uint = png.position; | |
png.writeUnsignedInt(type); | |
if ( data != null ) { | |
png.writeBytes(data); | |
} | |
var e:uint = png.position; | |
png.position = p; | |
c = 0xffffffff; | |
for (var i:int = 0; i < (e-p); i++) { | |
c = uint(crcTable[ | |
(c ^ png.readUnsignedByte()) & | |
uint(0xff)] ^ uint(c >>> 8)); | |
} | |
c = uint(c^uint(0xffffffff)); | |
png.position = e; | |
png.writeUnsignedInt(c); | |
} |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment