Run this command against your Azure Monitor logs:
ContainerLog
| where TimeGenerated >= ago(360d)
| project TimeGenerated, ContainerID, _BilledSize
| lookup kind=leftouter (
KubePodInventory
| where TimeGenerated >= ago(360d)
| sort by TimeGenerated desc
| project ContainerID, Namespace, PodLabel
| extend Labels=parse_json(PodLabel)[0]
| extend
LabelApp=tostring(Labels["app.kubernetes.io/name"]),
LabelInstance=tostring(Labels["app.kubernetes.io/instance"])
| distinct ContainerID, Namespace, LabelApp, LabelInstance
) on ContainerID
| extend BilledSizeGb=todouble(_BilledSize)/1000000000
| project TimeGenerated, Namespace, LabelApp, LabelInstance, BilledSizeGb
| summarize hint.strategy=shuffle TotalSizeGb=sum(BilledSizeGb) by bin(TimeGenerated, 1d), Namespace, LabelApp, LabelInstance
| order by TotalSizeGb desc, TimeGenerated desc
Return is on the following format:
TimeGenerated [UTC] | Namespace | LabelApp | LabelInstance | TotalSizeGb |
---|---|---|---|---|
7/4/2023, 12:00:00.000 AM | monitoring | loki | loki | 65.53869314785915 |
7/7/2023, 12:00:00.000 AM | monitoring | loki | loki | 52.8441286817879 |
6/25/2023, 12:00:00.000 AM | monitoring | loki | loki | 14.918708088920262 |
6/26/2023, 12:00:00.000 AM | dev | cart | cart-feat-availability-field | 8.21157037500891 |
6/24/2023, 12:00:00.000 AM | monitoring | loki | loki | 4.932387020003877 |
6/22/2023, 12:00:00.000 AM | monitoring | loki | loki | 4.8714318899974 |
7/10/2023, 12:00:00.000 AM | dev | cart | cart-develop | 3.8840713110003313 |
6/21/2023, 12:00:00.000 AM | monitoring | loki | loki | 2.398814486002009 |
6/26/2023, 12:00:00.000 AM | dev | cart | cart-develop | 2.180228478003188 |
7/11/2023, 12:00:00.000 AM | private-gpt | private-gpt | default | 1.4751339030008193 |
7/20/2023, 12:00:00.000 AM | private-gpt | private-gpt | default | 0.83576458100041 |
7/10/2023, 12:00:00.000 AM | private-gpt | private-gpt | default | 0.5564783410007007 |
7/17/2023, 12:00:00.000 AM | dev | cart | cart-feat-availability-field | 0.4378696729999755 |
7/3/2023, 12:00:00.000 AM | dev | cart | cart-feat-availability-field | 0.418866305000033 |
7/3/2023, 12:00:00.000 AM | dev | cart | cart-feat-makefile-refacto | 0.4104211710000661 |
7/10/2023, 12:00:00.000 AM | dev | cart | cart-feat-availability-field | 0.40920388300004507 |